南岳快讯 版权所有,是国内最具有亲和力的网站之一 [ 给我写信 ] [ 百度空间 ] [ 腾讯微博 ] [ 新浪微博 ]

当前位置   主页 > 科技 >

自由口模式下PLC与计算机的通信

发表于:2019-05-24 11:25 作者:新闻小编 来源:新闻小编

概述
  ----本例说明如何以自由协议实现计算机与S7-200的通信,计算机作为主站,可以实现对PLC从站各寄存器的读/写操作。

  ----计算机通过COM口发送指令到PLC的PORT0(或PORT1)口,PLC通过RCV接收指令,然后对指令进行译码,译码后调用相应的读/写子程序实现指令要求的操作,并返回指令执行的状态信息。

通信协议

  ----在自由口模式下,通信协议是由用户定义的。用户可以用梯形图程序调用接收中断、发送中断、发送指令(XMT)、接受指令(RCV)来控制通信操作。在自由口模式下,通信协议完全由梯形图程序控制。

指令格式定义

  计算机每次发送一个33字节长的指令来实现一次读/写操作,指令格式见表1 说明:

起始字符

  ----起始字符标志着指令的开始,在本例中被定义为ASCII码的g,不同的PLC从站可以定义不同的起始字符以接收真对该PLC的指令。

指令类型

  ----该字节用来标志指令的类型,在本例中05H代表读操作,06H代表写操作。

目标PLC站地址

  ----目标PLC站地址占用指令的B2、B3两个字节,以十六进制ASCII码的格式表示目标PLC的站地址。

目标寄存器地址

  ----在PLC内部可以用4个字节来表示一个寄存器的地址(但不能表示一个位地址)。前两个字节表示寄存器类型,后两个字节表示寄存器号。

  00 00(H): I寄存器区
  01 00(H): Q寄存器区
  02 00(H): M寄存器区
  08 00(H): V寄存器区

例如:

  IB000的地址可表示为 00 00 00 00(H)
  VB100的地址可表示为 08 00 00 64(H)

读/写字节数M

  ----当读命令时,始终读回从目标寄存器开始的连续8个字节的数据(转换为十六进制ASCII码后占用16个字节),可以根据自己的需要取用,M可以任意写入。

  ----当写命令时,M表示的是要写入数据的十六进制ASCII码所占用的字节数。例如要写入1个字节的数据,数据在指令中以十六进制ASCII码表示,它将占用2个字节,此时应向M中写入02。同理,如果要写入5个字节的数据,M中应写入0A。

要写入的数据

  ----要写入的数据在指令中以十六进制ASCII码的格式表示,占用指令的B14-B29共16个字节。数据区必须填满,但只有前M个字节的数据会被写入目标寄存器。一条指令最多可以写入8个字节的数据(此时M中应写入10,代表十进制的16)

BCC校验码

  ----在传输过程中,指令有可能受到任何的干扰而使原来的数据信号发生扭曲,此时的指令当然是错误的,为了侦测指令在传输过程中发生的错误,接收方必须对指令作进一步的确认工作,以防止错误的指令被执行,最简单的方法就是使用校验码。BCC校验码的方法就是将要传送的字符串的ASCII码以字节为单位作异或和,并将此异或和作为指令的一部分传送出去;同样地,接收方在接到指令后,以相同的方式对接收到的字符串作异或和,并与传送方所送过来的值作对比,若其值相等,则代表接收到的指令是正确的,反之则是错误的。

  ----在本例中,bcc为指令B1到B29的异或和,BCC为bcc的十六进制ASCII码。

  ----bcc=B1 xor B2 xor B3 xor B4 xor xor B29

结束字符

  ----结束字符标志着指令的结束,在本例中被定义为ASCII码的G,不同的PLC从站可以定义不同的结束字符以接收真对该PLC的指令。

  PLC在接到上位机指令后,将发送一个21字节长反馈信息,格式见表2

说明:

起始字符

  ----起始字符标志着反馈信息的开始,在本例中被定义为ASCII码的g,不同的PLC从站可以定义不同的起始字符,这样上位机可以根据信息的起始字符来判断反馈信息的来源。

状态信息

  ----该字节包含指令执行的状态信息,在本例中

  01H 代表 读取正确
  02H 代表 写入正确
  03H 代表 BCC校验码错误
  04H 代表 指令不合法

数据区

  ----反馈信息的B3到B18为读指令所要读取的数据,以十六进制ASCII码表示。

BCC校验码

  ----与上位机指令中的BCC校验码类似,它是反馈信息B3到B18的异或和。

结束字符

  ----结束字符标志着反馈信息的结束,在本例中被定义为26H。

指令中为何要使用ASCII码

  ----一条指令除包含数据外,还包含必要的控制字(起始字符、结束字符、指令类型等)。如果指令中的数据直接以其原本的形式传输,则不可避免的会与指令中的控制字发生混淆。

  ----例如本例中,指令的起始字符为g,其ASCII码值为67H,结束字符为G,其ASCII码值为47H。假设要写入的数据中也有47H,并且数据直接以其原本的形式传输,则PLC会因为接收到了数据中的47H而停止接收,这样PLC接收到的指令将是一个不完整的非法指令,很可能造成PLC的误动作。

  ----为了避免这种情况的发生,可以用文本来传送二进制数据。通过以16进制ASCII码的格式描述数据,每个二进制的字节都可以表示成一对ASCII编码,这对编码表示这个字节的两个16进制字符。这种格式可以表示任何的数值,仅仅使用ASCII代码的30H到39H(表示0到9)和41H到46H(表示A到F)。ASCII码的其余部分可以用作控制字(起始标志、结束标志、指令类型等)。这样,数据中的47H以ASCII码的形式进行传送就变成了34H 37H 两个字节,从而避免了PLC因接收到数据中的47H而停止接收的错误。

表1 上位机指令格式

表2 反馈信息格式

PLC程序执行过程

  ----PLC在第一次扫描时执行初始化子程序,对端口及RCV指令进行初始化。初始化完成后,运行RCV指令使端口处于接受状态。

  ----RCV会将以g开头G结尾的指令保存到接收缓冲区,并同时产生接收完成中断。

  ----RCVcomplete中断服务程序用来处理接收完成中断事件,它会将接收缓冲区中的十六进制ASCII码还原成数据并保存,同时置位Verify子程序的触发条件(M0.1)。 ----Verify子程序首先复位本身的触发条件以防止子程序被重复调用,然后求出接收缓冲区中指令的BCC校验码并与指令中的BCC校验码进行比对。如果相等则置BCC码校验正确的标志位(M0.0)为1;如果指令格式正确(指令的结束标志在接收缓冲区中特定的位置VB133)而BCC码不相等,则发送代表BCC校验码错误的反馈信息;如果指令格式不正确(VB133中不是指令的结束标志),则返回代表指令格式错误的反馈信息。

  ----Read子程序的触发条件为:指令中的站地址与本机站地址相符、指令类型为读指令、BCC检验码正确。当条件满足时,Read子程序被执行。Read子程序首先禁止RCV,然后将指令所要读取的数据转换成十六进制ASCII码并写入发送缓冲区、计算BCC检验码、最后发送反馈信息。

  ----Write子程序的触发条件为:指令中的站地址与本机站地址相符、指令类型为写指令、BCC检验码正确。当条件满足时,Write子程序被执行。Write子程序首先禁止RCV,然后将指令中的数据写入目标寄存器,最后发送代表写入正确的反馈信息。

  ----PLC每接到一条指令后都会发送一条反馈信息,当反馈信息发送完成时,会产生发送完成中断,XMTcomplete中断服务程序用来处理发送完成中断事件。在XMTcomplete中断服务程序中所要执行的操作包括:复位BCC校验码正确的标志位(M0.0);允许RCV;bcc码寄存器清零;重新装入用于计算BCC校验码的地址指针;接收缓冲区中存放指令结束字符的字节VB133清零(用来判断下一条指令格式是否正确)。

PLC寄存器地址分配

  ----此程序占用PLC寄存器的VB100-VB199,内部继电器占用M0.0和M0.1。寄存器地址分配见表3、表4、表5、表6。

表3 接收缓冲区

表4 译码区

表5 发送缓冲区


表6 其它

程序清单

主程序:
NETWORK 1
LD SM0.1 //第一次扫描调用初始化子程序
CALL initialize

NETWORK 2
LDB= VB134, VB199 //指令中的站地址与本机站地址相符
AB= VB102, 5 //指令类型为读指令
A M0.0 //BCC码校验正确
CALL Read //调用读子程序

NETWORK 3
LDB= VB134, VB199 //指令中的站地址与本机站地址相符
AB= VB102, 6 //指令类型为写指令
A M0.0 //BCC码校验正确
CALL Write //调用写子程序

NETWORK 4
LD M0.1 //指令接收完成后调用BCC码校验子程序
CALL Verify

NETWORK 5
LD SM4.5 //当端口空闲时启动RCV
RCV VB100, 0


Read子程序:
NETWORK 1
LD SM0.0 //停止端口0的接收
R SM87.7, 1
R M0.0, 1
RCV VB100, 0

NETWORK 2
LD SM0.0 //将数据写入发送缓冲区
MOVB 103, VB154
MOVB 1, VB155
HTA *VD135, VB156, 16
MOVB 26, VB174
MOVB 21, VB153

NETWORK 3
LD SM0.0 //计算BCC校验码
FOR VW177, +1, +16

NETWORK 4
LD SM0.0
XORB *VD181, VB180

NETWORK 5
LD SM0.0
INCD VD181

NETWORK 6
NEXT

NETWORK 7
LD SM0.0
HTA VB180, VB172, 2 //BCC校验码写入发送缓冲区

NETWORK 8
LD SM4.5 //发送反馈信息
XMT VB153, 0


Write子程序:
NETWORK 1
LD SM0.0 //停止端口0的接收
R SM87.7, 1
R M0.0, 1
RCV VB100, 0

NETWORK 2
LD SM0.0 //装入要写如数据源的地址指针
MOVD VB115, VD145

NETWORK 3
LD SM0.0 //写入数据
ATH *VD145, *VD135, VB139

NETWORK 4
LD SM0.0 //指令执行的反馈信息写入发送缓冲区
MOVB 21, VB153
MOVB 103, VB154
MOVB 2, VB155
MOVB 26, VB174

NETWORK 5
LD SM4.5 //发送指令执行的反馈信息
XMT VB153, 0


Verify子程序:
NETWORK 1
LD SM0.0
R M0.1, 1 //复位verify子程序的执行条件

NETWORK 2
LD SM0.0 //计算BCC码
FOR VW175, +1, +29

NETWORK 3
LD SM0.0
XORB *VD149, VB179

NETWORK 4
LD SM0.0
INCD VD149

NETWORK 5
NEXT

NETWORK 6
LDB= VB179, VB140 //当BCC码校验正确时,M0.0置1
AB= VB133, 71
S M0.0, 1

NETWORK 7
LDB= VB133, 71 //BCC码错误时发送反馈信息
AB VB179, VB140
MOVB 21, VB153
MOVB 103, VB154
MOVB 3, VB155
MOVB 26, VB174
R SM87.7, 1
RCV VB100, 0
XMT VB153, 0

NETWORK 8
LDB VB133, 71 //指令格式错误或RCV超时时发送反馈信息
MOVB 21, VB153
MOVB 103, VB154
MOVB 4, VB155
MOVB 26, VB174
R SM87.7, 1
RCV VB100, 0
XMT VB153, 0


Initialize子程序:
NETWORK 1
LD SM0.0
MOVB 9, SMB30 //0口9600,N,8,1

NETWORK 2
LD SM0.0 //RCV指令初始化
MOVB 16#EC, SMB87
MOVB 103, SMB88
MOVB 71, SMB89
MOVB +1000, SMW92
MOVB 35, SMB94
R SM87.2, 1

NETWORK 3
LD SM0.0
ATCH RCVcomplete, 23 //连接口0接收完成的中断

NETWORK 4
LD SM0.0
ATCH XMTcomplete, 9 //连接口0发送完成的中断

NETWORK 5
LD SM0.0
ENI //中断允许

NETWORK 6
LD SM0.0
MOVB 2, VB199 //将本机站地址装入寄存器

NETWORK 7
LD SM0.0
MOVB VB102, VD149 //装入地址指针
MOVB 0, VB179 //BCC码寄存器清零
MOVB VB156, VD181 //装入地址指针
MOVB 0, VB180 //BCC码寄存器清零


RCVcomplete中断程序
NETWORK 1
LD SM0.0
ATH VB103, VB134, 2 //指令译码(ASCII码到十六进制)
ATH VB105, VB135, 8
ATH VB113, VB139, 2
ATH VB131, VB140, 2
S M0.1, 1 //置位Verify子程序的触发条件
MOVB 0, VB179 //BCC码寄存器清零
MOVD VB102, VD149 //装入地址指针


XMTcomplete中断程序
NETWORK 1
LD SM0.0
R M0.0, 1 //复位BCC校验码正确的标志位
S SM87.7, 1 //允许口0进行接收
MOVB 0, VB179 //BCC校验码寄存器清零
MOVB 0, VB180 //BCC校验码寄存器清零
MOVD VB102, VD149 //重新装入地址指针
MOVD VB156, VD181
MOVB 0, VB133 //接收缓冲区中存放指令结束字符的字节

本文链接地址: http://www.shennongcaotang.com/keji/920.html

栏目:科技      围观:

相关阅读

本月热点